The following set of syntax productions define how namespace and datatype declarations expressed in accordance with this standard may be represented as XML processing instructions. Syntax productions for pio, pic, name-token-group, NCName, URI, lit, lita and s are given in .

DTD-extension-processing-instruction ::= pio "DSDL-9" s (namespace-prefix-binding-declaration | namespace-name-binding-declaration | wildcard-namespace-qualifier-declaration | default-datatype-library-declaration | datatype-library-prefix-binding-declaration | datatype-binding-declaration | external-declarations-subset-locator) pic

namespace-prefix-binding-declaration ::= "namespace-prefix-binding" s "namespace-iri=" IRI-literal s "prefix=" prefix-literal

namespace-name-binding-declaration ::= "namespace-name-binding" s "namespace-iri=" IRI-literal s "applies-to-element=" name-locator-literal

wildcard-namespace-qualifier-declaration ::= "wildcard-namespace-qualifier" s "namespace-iri=" wildcard-namespace-literal s "applies-to-element=" name-locator-literal

wildcard-namespace-literal ::= ((lit wildcard-namespace-sequence lit) | (lita wildcard-namespace-sequence lita))

wildcard-namespace-sequence ::= IRI (s IRI)*

name-locator-literal ::= ((lit name-locator-sequence lit) | (lita name-locator-sequence lita))

name-locator-sequence ::= (s)? (name-token-group | any-name) (s)?

any-name ::= "#any"

default-datatype-library-declaration ::= "default-datatype-library-iri=" IRI-literal

datatype-library-prefix-binding-declaration ::= "datatype-library-prefix-binding" s "datatype-library-iri=" IRI-literal s "prefix=" prefix-literal

datatype-binding-declaration ::= "datatype-binding" s "datatype-name=" datatype-literal s (("applies-to-element=" name-locator-literal) | ("applies-to-attribute=" name-locator-literal "of-element" name-locator-literal ))

datatype-name ::= NCName

datatype-qname ::= prefix ":" datatype-name

datatype-literal ::= ((lit (datatype-name | datatype-qname) lit) | (lita (datatype-name | datatype-qname) lita))

prefix-literal ::= ((lit prefix lit) | (lita prefix lita))

prefix ::= NCName

external-declarations-subset-locator ::= "external-declarations-subset" s "location=" IRI-literal s "syntax=" ((lit ("pi" | "xml") lit) | (lita ("pi" | "xml") lita))

IRI-literal ::= ((lit IRI lit) | (lita IRI lita))

IRI ::= URI

NOTE - An IRI must be a URI that conforms to .

The following schema in RELAX NG Compact Syntax specifies how a set of namespace and datatype declarations expressed in accordance with this standard may be represented as an XML document.

datatypes xsd = "http://www.w3.org/2001/XMLSchema-datatypes"
default namespace = "http://dsdl.org/dsdl-9"

start = document

document = element dtd-extension { head, body }

head = (element applies-to-dtd {public | system} )*

public = element public {text}, system?

system = element system {xsd:anyURI}

body = ( namespace-prefix-binding |  
         namespace-name-binding | 
         wildcard-namespace-qualifier | 
         default-datatype-library | 
         datatype-library-prefix-binding | 
         datatype-binding )+

namespace-prefix-binding = element namespace-prefix-binding 
                           { namespace-iri, prefix }

namespace-name-binding = element namespace-name-binding 
                         { namespace-iri, applies-to-element}

applies-to-element = element applies-to-element 
                     { (name+ | any-name) }

applies-to-attribute = element applies-to-attribute 
                       { (name+ | any-name), of-element-names }

of-element-names = element of-element-names 
                   { name+ | any-name }

name = element name {xsd:NMTOKEN}

any-name = element any {empty}

wildcard-namespace-qualifier = element wildcard-namespace-qualifier 
                               { (namespace-iri+, applies-to-element) }

default-datatype-library = element default-datatype-library 
                           { library-iri }

datatype-library-prefix-binding = element datatype-library-prefix-binding 
                                  { (library-iri, prefix) }

library-iri = element library-iri {xsd:anyURI}

datatype-binding = element datatype-binding 
                   { name, (applies-to-element | applies-to-attribute) }

namespace-iri = element namespace-iri {xsd:anyURI}

prefix = element prefix {xsd:NMTOKEN}       

DTD extension declarations in processing instruction syntax must be located in one or more of the following locations:

• a DTD's external subset,

• the local subset of a DTD declaration, or

• an external declarations subset whose location IRI is specified by declaring an external declarations subset locator within the DTD's external or local subset.

DTD extension declarations in XML document syntax must be located as an external declarations subset whose location IRI is specified by declaring an external declarations subset locator within the DTD's external or local subset.

The ordering of all the DTD extension declarations that are associated with a DTD is the same ordering that would be obtained by substituting all extension declarations in XML document syntax with equivalent declarations in processing instruction syntax and by treating each external declarations subset were an external parameter entity of the DTD and its corresponding locator declaration were a reference to that external parameter entity.

A namespace IRI may be associated with the names of any elements that are declared in a DTD, including both qualified and unqualified names. A namespace IRI may also be declared as a constraint on the content of an element whose declared content model is "ANY".

A datatype may be associated with a specified element or attribute, by declaring a datatype name together with the name of the element or attribute to which it applies.

Every datatype name must be associated with a declared datatype library. Unqualified datatype names are associated with a default datatype library, while qualified datatype names are associated with declared datatype libraries by declaring a binding between the qualifying prefix and the associated datatype library.

The IRI specified in either a datatype library prefix binding declaration or a default datatype library declaration must identify a datatype library, for example a library that conforms to Part 5 of this International Standard (DTLL).

If two or more datatype declarations apply to the same element content or attribute value, the second and subsequent declarations are ignored.